鼠标钩子回调函数的格式在哪点一下可以收回钩子

两个步骤：

一、创建DLL，并在DLL中实现挂钩设置，释放和挂钩功能；

二、创建另一个项目以调用测试。

第1步：制作一个DLL

首先创建一个DLL项目，自动初始代码如下（删除注释）：

library Project1;
uses
  SysUtils,
  Classes;
{$R *.res}
begin
end.

//把工程保存为 MyHook.dpr, 并实现如下:
library MyHook;
uses
  SysUtils,
  Windows,  {钩子函数都来自 Windows 单元}
  Messages, {消息 WM_LBUTTONDOWN 定义在 Messages 单元}
  Classes;
{$R *.res}
var
  hook: HHOOK; {钩子变量}
{钩子函数, 鼠标消息太多(譬如鼠标移动), 必须要有选择, 这里选择了鼠标左键按下}
function MouseHook(nCode: Integer; wParam: WPARAM; lParam: LPARAM): LRESULT; stdcall;
begin
  if wParam = WM_LBUTTONDOWN then
  begin
    MessageBeep(0);
  end;
  Result := CallNextHookEx(hook, nCode, wParam, lParam);
end;
{建立钩子}
function SetHook: Boolean; stdcall;
begin
  hook := SetWindowsHookEx(WH_MOUSE, @MouseHook, HInstance, 0);
  Result := hook <> 0;
end;
{释放钩子}
function DelHook: Boolean; stdcall;
begin
  Result := UnhookWindowsHookEx(hook);
end;
{按 DLL 的要求输出函数}
exports
  SetHook name 'SetHook',
  DelHook name 'DelHook',
  MouseHook name 'MouseHook';
//SetHook, DelHook, MouseHook; {如果不需要改名, 可以直接这样 exports}
begin
end.

注意：SetWindowsHookEx的第一个参数WH_MOUSE表示这是一个鼠标钩；第四个参数0表示它是全局的。

鼠标钩子回调函数的格式在这里

然后按Ctrl + F9进行编译，将在项目目录中生成与项目同名的文件，这里是：MyHook.dll。

第2步：调用

创建新项目后，将其保存，然后将刚刚制作的MyHook.dll复制到该项目目录中；

然后添加两个按钮，实现如下：

unit Unit1;
interface
uses
  Windows, Messages, SysUtils, Variants, Classes, Graphics, Controls, Forms,
  Dialogs, StdCtrls;
type
  TForm1 = class(TForm)
    Button1: TButton;
    Button2: TButton;
    procedure Button1Click(Sender: TObject);
    procedure Button2Click(Sender: TObject);
  end;
  {DLL 中的函数声明}
  function SetHook: Boolean; stdcall;
  function DelHook: Boolean; stdcall;
var
  Form1: TForm1;
implementation
{$R *.dfm}
{DLL 中的函数实现, 也就是说明来自那里, 原来叫什么名}
function SetHook; external 'MyHook.dll' name 'SetHook';
function DelHook; external 'MyHook.dll' name 'DelHook';
{建立钩子}
procedure TForm1.Button1Click(Sender: TObject);
begin
  SetHook;
end;
{销毁钩子}
procedure TForm1.Button2Click(Sender: TObject);
begin
  DelHook;
end;
end.

测试：单击第一个按钮后，挂钩被激活；无论在何处单击鼠标，鼠标左键都将“单击”；单击第二个按钮以缩回挂钩。

以下是动态调用的方法，功能与上面完全相同：

unit Unit1;
interface
uses
  Windows, Messages, SysUtils, Variants, Classes, Graphics, Controls, Forms,
  Dialogs, StdCtrls;
type
  TForm1 = class(TForm)
    Button1: TButton;
    Button2: TButton;
    procedure Button1Click(Sender: TObject);
    procedure Button2Click(Sender: TObject);
  end;
var
  Form1: TForm1;
implementation
{$R *.dfm}
{要先要定义和 DLL 中同样参数和返回值的的函数类型}
type
  TDLLFun = function: Boolean; stdcall;
  {现在需要的 DLL 中的函数的格式都是这样, 定义一个就够了}
var
 h: HWND;                   {声明一个 DLL 句柄}
 SetHook, DelHook: TDLLFun; {声明两个 TDLLFun 变量}
{载入 DLL 并调用其函数}
procedure TForm1.Button1Click(Sender: TObject);
begin
  h := LoadLibrary('MyHook.dll'); {载入 DLL 并获取句柄}
  if h<>0 then
  begin
    SetHook := GetProcAddress(h, 'SetHook'); {让 SetHook 指向 DLL 中相应的函数}
    DelHook := GetProcAddress(h, 'DelHook'); {让 DelHook 指向 DLL 中相应的函数}
  end else ShowMessage('Err');
  SetHook; {执行钩子建立函数, 这里的 SetHook 和它指向的函数是同名的, 也可以不同名}
end;
{销毁钩子, 并释放 DLL}
procedure TForm1.Button2Click(Sender: TObject);
begin
  DelHook;        {执行钩子释放函数}
  FreeLibrary(h); {释放 DLL 资源}
end;
end.

为什么全局钩子必须位于DLL中？

因为每个EXE都是独立且封闭的进程； DLL是系统的通用资源。

如果一个钩子不是面向系统的，恐怕它没有多大意义。因此，实际上，钩子无法与DLL分开。

问大家：全局钩子可以用“包装”制成吗？我还没有尝试过。

本文来自电脑杂谈，转载请注明本文网址：
http://www.pc-fly.com/a/bofangqi/article-366909-1.html